Routines (alphabetical) > Routines: C > CW_ZOOM

# CW_ZOOM

The CW_ZOOM function creates a compound widget that displays two images: an original image in one window and a zoomed portion of the original image in another. The user can select the center of the zoom region, the zoom scale, the interpolation style, and the method of indicating the zoom center.

This routine is written in the IDL language. Its source code can be found in the file `cw_zoom.pro` in the `lib` subdirectory of the IDL distribution.

### Using CW_ZOOM

The value of the CW_ZOOM widget is the original, un-zoomed image to be displayed (a two-dimensional array). To change the contents of the CW_ZOOM widget, use the command:

WIDGET_CONTROL, id, SET_VALUE = array

where `id` is the widget ID of the CW_ZOOM widget and `array` is the image array. The value of CW_ZOOM cannot be set until the widget has been realized. Note that the size of the original window, set with the XSIZE and YSIZE keywords to CW_ZOOM, must be the size of the input array.

To return the current zoomed image as displayed by CW_ZOOM in the variable `array`, use the command:

WIDGET_CONTROL, id, GET_VALUE = array

## Examples

The following code samples illustrate a use of the CW_ZOOM widget. First, create an event-handler. Note that clicking on the widget’s “Zoom” button displays IDL’s help output on the console.

PRO widzoom_event, event

WIDGET_CONTROL, event.id, GET_UVALUE=uvalue

CASE uvalue OF

'ZOOM': HELP, /STRUCT, event

'DONE': WIDGET_CONTROL, event.top, /DESTROY

ENDCASE

END

Next, create the widget program:

PRO widzoom

OPENR, lun, FILEPATH('people.dat', $

SUBDIR = ['examples','data']), /GET_LUN

image=BYTARR(192,192, /NOZERO)

READU, lun, image

FREE_LUN, lun

sz = SIZE(image)

base=WIDGET_BASE(/COLUMN)

zoom=CW_ZOOM(base, XSIZE=sz[1], YSIZE=sz[2], UVALUE='ZOOM')

done=WIDGET_BUTTON(base, VALUE='Done', UVALUE='DONE')

WIDGET_CONTROL, base, /REALIZE

WIDGET_CONTROL, zoom, SET_VALUE=image

XMANAGER, 'widzoom', base

END

Once you have entered these programs, type “widzoom” at the IDL command prompt to run the widget application.

## Syntax

Result = CW_ZOOM( Parent [, /FRAME] [, MAX=scale] [, MIN=scale] [, RETAIN={0 | 1 | 2}] [, SAMPLE=value] [, SCALE=value] [, TAB_MODE=value] [, /TRACK] [, UNAME=string] [, UVALUE=value] [, XSIZE=width] [, X_SCROLL_SIZE=width] [, X_ZSIZE=zoom_width] [, YSIZE=height] [, Y_SCROLL_SIZE=height] [, Y_ZSIZE=zoom_height] )

## Return Value

This function returns the widget ID of the newly-created zoom widget.

## Arguments

### Parent

The widget ID of the parent widget.

## Keywords

### FRAME

If set, a frame will be drawn around the widget. The default is FRAME = 0.

### MAX

The maximum zoom scale, which must be greater than or equal to 1. The default is 20.

### MIN

The minimum zoom scale, which must be greater than or equal to 1. The default is 1.

### RETAIN

Set this keyword to zero, one, or two to specify how backing store should be handled for both windows. RETAIN=0 specifies no backing store. RETAIN=1 requests that the server or window system provide backing store. RETAIN=2 specifies that IDL provide backing store directly.

### SAMPLE

Set to zero for bilinear interpolation, or to a non-zero value for nearest neighbor interpolation. Bilinear interpolation gives higher quality results, but requires more time. The default is 0.

### SCALE

The initial integer scale factor to use for the zoomed image. The default is SCALE = 4. The scale must be greater than or equal to 1.

### TAB_MODE

Set this keyword to one of the values shown in the table below to determine how the widget hierarchy can be navigated using the Tab key. The TAB_MODE setting is inherited by lower-level bases and child widgets unless it is explicitly set on an individual widget.

Note: It is not possible to tab to disabled (SENSITIVE=0) or hidden (MAP=0) widgets.

Valid settings are:

Value | Description
0 | Disable navigation onto or off of the widget. This is the default. Child widgets automatically inherit the tab mode of the parent base as described in Inheriting the TAB_MODE Value.
1 | Enable navigation onto and off of the widget.
2 | Navigate only onto the widget.
3 | Navigate only off of the widget.

Note: In widget applications on the UNIX platform, the Motif library controls what widgets are brought into and released from focus using tabbing. The TAB_MODE keyword value is always zero, and any attempt to change it is ignored when running a widget application on the UNIX platform. Tabbing behavior may vary significantly between UNIX platforms; do not rely on a particular behavior being duplicated on all UNIX systems.

### TRACK

Set this keyword and events will be generated continuously as the cursor is moved across the original image. If not set, events will only be generated when the mouse button is released. Note: On slow systems, /TRACK performance can be inadequate. The default is 0.

### UNAME

Set this keyword to a string that can be used to identify the widget in your code. You can associate a name with each widget in a specific hierarchy, and then use that name to query the widget hierarchy and get the correct widget ID.

To query the widget hierarchy, use the WIDGET_INFO function with the FIND_BY_UNAME keyword. The UNAME should be unique to the widget hierarchy because the FIND_BY_UNAME keyword returns the ID of the first widget with the specified name.

### UVALUE

The “user value” to be assigned to the widget.

### XSIZE

The width of the window (in pixels) for the original image. The default is XSIZE = 500. Note that XSIZE must be set to the width of the original image array for the image to display properly.

### X_SCROLL_SIZE

The width of the visible part of the original image. This may be smaller than the actual width controlled by the XSIZE keyword. The default is 0, for no scroll bar.

### X_ZSIZE

The width of the window for the zoomed image. The default is 250.

### YSIZE

The height of the window (in pixels) for the original image. The default is 500. Note that YSIZE must be set to the height of the original image array for the image to display properly.

### Y_SCROLL_SIZE

The height of the visible part of the original image. This may be smaller than the actual height controlled by the YSIZE keyword. The default is 0, for no scroll bar.

### Y_ZSIZE

The height of the window for the zoomed image. The default is 250.

### Keywords to WIDGET_CONTROL and WIDGET_INFO

The widget ID returned by most compound widgets is actually the ID of the compound widget’s base widget. This means that many keywords to the WIDGET_CONTROL and WIDGET_INFO routines that affect or return information on base widgets can be used with compound widgets.

In addition, you can use the GET_VALUE and SET_VALUE keywords to WIDGET_CONTROL to obtain or set the value of the zoom widget. The value of the CW_ZOOM widget is the original, un-zoomed image to be displayed (a two-dimensional array). To change the contents of the CW_ZOOM widget, use the command:

WIDGET_CONTROL, id, SET_VALUE = array

where `id` is the widget ID of the CW_ZOOM widget and `array` is the image array. The value of CW_ZOOM cannot be set until the widget has been realized. Note that the size of the original window, set with the XSIZE and YSIZE keywords to CW_ZOOM, must be the size of the input array.

To return the current zoomed image as displayed by CW_ZOOM in the variable `array`, use the command:

WIDGET_CONTROL, id, GET_VALUE = array

Creating a Compound Widget for a more complete discussion of controlling compound widgets using WIDGET_CONTROL and WIDGET_INFO.

## Widget Events Returned by the CW_ZOOM Widget

When the “Report Zoom to Parent” button is pressed, this widget generates event structures with the following definition:

event = {ZOOM_EVENT, ID:0L, TOP:0L, HANDLER:0L, $

XSIZE:0L, YSIZE:0L, X0:0L, Y0:0L, X1:0L, Y1:0L }

This specifies the dimensions of the zoomed image and the corresponding coordinates within the original image. The XSIZE and YSIZE fields contain the dimensions of the zoomed image. The X0 and Y0 fields contain the coordinates of the lower left corner of the original image, and the X1 and Y1 fields contain the coordinates of the upper right corner of the original image.

## Version History

Pre 4.0 | Introduced
6.1 | Added TAB_MODE keyword

## See Also

ZOOM Procedure, ZOOM_24 Procedure