Routines (alphabetical) > Routines: H > HDF Routines > HDF_VD_ATTRSET

# HDF_VD_ATTRSET

The HDF_VD_ATTRSET procedure writes a VData attribute or a VData field attribute to the currently attached HDF VData structure. If no data type keyword is specified, the data type of the attribute value is used.

## Syntax

HDF_VD_ATTRSET, VData, FieldID, Attr_Name, Values [, Count] [, /BYTE] [, /DFNT_CHAR8] [, /DFNT_FLOAT32] [, /DFNT_FLOAT64] [, /DFNT_INT8] [, /DFNT_INT16] [, /DFNT_INT32] [, /DFNT_UCHAR8] [, /DFNT_UINT8] [, /DFNT_UINT16] [, /DFNT_UINT32] [, /DOUBLE] [, /FLOAT] [, /INT] [, /LONG] [, /SHORT] [, /STRING] [, /UINT ] [, /ULONG ]

## Arguments

### VData

The VData handle returned by a previous call to HDF_VD_ATTACH.

Note: The VData structure must have been attached in write mode in order for attributes to be correctly associated with a VData or one of its fields. If the VData is not write accessible, HDF does not return an error; instead, the attribute information is written to the file but is not associated with the VData.

### FieldID

A zero-based index specifying the field, or a string containing the name of the field within the VData whose attribute is to be set. If FieldID is set to -1, the attribute will be attached to the VData itself.

### Attr_Name

A string containing the name of the attribute to be written.

### Values

The attribute value(s) to be written.

Note: Attributes to be written as characters may not be a multi-dimensional array (e.g. if being converted from byte values) or an array of IDL strings.

### Count

An optional integer argument specifying how many values are to be written. Count must be less than or equal to the number of elements in the Values argument. If not specified, the actual number of values present will be written.

## Keywords

### BYTE

Set this keyword to indicate that the attribute is composed of bytes. Data will be stored with the HDF DFNT_UINT8 data type. Setting this keyword is the same as setting the DFNT_UINT8 keyword.

### DFNT_CHAR8

Set this keyword to create an attribute of HDF type DFNT_CHAR8. Setting this keyword is the same as setting the STRING keyword.

### DFNT_FLOAT32

Set this keyword to create an attribute of HDF type DFNT_FLOAT32. Setting this keyword is the same as setting the FLOAT keyword.

### DFNT_FLOAT64

Set this keyword to create an attribute of HDF type DFNT_FLOAT64. Setting this keyword is the same as setting the DOUBLE keyword.

### DFNT_INT8

Set this keyword to create an attribute of HDF type DFNT_INT8.

Note: IDL does not have a signed 8-bit integer type. When writing the data to the file using DFNT_INT8, byte values from 0-127 will be written unchaged, while byte values from 128-255 will be wrapped into the range -127 to -1. When reading data of type DFNT_INT8 from the file into IDL, values from 0-127 will be read in unchanged, while values from -127 to -1 will be wrapped into the byte range 128 to 255.

### DFNT_INT16

Set this keyword to create an attribute of HDF type DFNT_INT16. Setting this keyword is the same as setting either the INT keyword or the SHORT keyword.

### DFNT_INT32

Set this keyword to create an attribute of HDF type DFNT_INT32. Setting this keyword is the same as setting the LONG keyword.

### DFNT_UCHAR8

Set this keyword to create an attribute of HDF type DFNT_UCHAR8.

### DFNT_UINT8

Set this keyword to create an attribute of HDF type DFNT_UINT8. Setting this keyword is the same as setting the BYTE keyword.

### DFNT_UINT16

Set this keyword to create an attribute of HDF type DFNT_UINT16.

### DFNT_UINT32

Set this keyword to create an attribute of HDF type DFNT_UINT32.

### DOUBLE

Set this keyword to indicate that the attribute is composed of double-precision floating-point values. Data will be stored with the HDF type DFNT_FLOAT64. Setting this keyword is the same as setting the DFNT_FLOAT64 keyword.

### FLOAT

Set this keyword to indicate that the attribute is composed of single-precision floating-point values. Data will be stored with the HDF type DFNT_FLOAT32 data type. Setting this keyword is the same as setting the DFNT_FLOAT32 keyword.

### INT

Set this keyword to indicate that the attribute is composed of 16-bit integers. Data will be stored with the HDF type DFNT_INT16 data type. Setting this keyword is the same as setting either the SHORT keyword or the DFNT_INT16 keyword.

### LONG

Set this keyword to indicate that the attribute is composed of longword integers. Data will be stored with the HDF type DFNT_INT32 data type. Setting this keyword is the same as setting the DFNT_INT32 keyword.

### SHORT

Set this keyword to indicate that the attribute is composed of 16-bit integers. Data will be stored with the HDF type DFNT_INT16 data type. Setting this keyword is the same as setting either the INT keyword or the DFNT_INT16 keyword.

### STRING

Set this keyword to indicate that the attribute is composed of strings. Data will be stored with the HDF type DFNT_CHAR8 data type. Setting this keyword is the same as setting the DFNT_CHAR8 keyword.

### UINT

Set this keyword to indicate that the attribute is composed of unsigned 2-byte integers. Data will be stored with the HDF type DFNT_UINT16 data type. Setting this keyword is the same as setting the DFNT_UINT16 keyword.

### ULONG

Set this keyword to indicate that the attribute is composed of unsigned longword integers. Data will be stored with the HDF type DFNT_UINT32 data type. Setting this keyword is the same as setting the DFNT_UINT32 keyword.

## Examples

; Open an HDF file.

fid = HDF_OPEN(FILEPATH('vattr_example.hdf',$

SUBDIRECTORY = ['examples', 'data']), /RDWR)

; Locate and attach an existing vdata.

vdref = HDF_VD_FIND(fid, 'MetObs')

vdid = HDF_VD_ATTACH(fid, vdref, /WRITE)

; Attach two attributes to the vdata.

HDF_VD_ATTRSET, vdid, -1, 'vdata_contents', $

'Ground station meteorological observations.'

HDF_VD_ATTRSET, vdid, -1, 'num_stations', 10

; Attach an attribute to one of the fields in the vdata.

HDF_VD_ATTRSET, vdid, 'TempDP', 'field_contents', $

'Dew point temperature in degrees Celsius.'

; Get the number of attributes associated with the vdata.

num_vdattr = HDF_VD_NATTRS(vdid, -1)

PRINT, 'Number of attributes attached to vdata MetObs: ', $ num_vdattr

; Get information for one of the vdata attributes by first finding

; the attribute's index number.

attr_index = HDF_VD_ATTRFIND(vdid, -1, 'vdata_contents')

HDF_VD_ATTRINFO, vdid, 1, attr_index, $

NAME = attr_name,DATA = metobs_contents

HELP, attr_name, metobs_contents

; Get information for another vdata attribute using the

; attribute's name.

HDF_VD_ATTRINFO, vdid, -1, 'num_stations', DATA = num_stations, $ HDF_TYPE = hdftype, TYPE = idltype

HELP, num_stations, hdftype,idltype

PRINT, num_stations

; Get the number of attributes attached to the vdata field

; TempDP.

num_fdattr = HDF_VD_NATTRS(vdid, 'TempDP')

PRINT, 'Number of attributes attached to field TempDP: ', $ num_fdattr

; Get the information for the vdata field attribute.

HDF_VD_ATTRINFO, vdid, 'TempDP', 'field_contents', $

COUNT = count, HDF_TYPE = hdftype, TYPE = idltype, $

DATA = dptemp_attr

HELP, count, hdftype, idltype, dptemp_attr

; End access to the vdata.

HDF_VD_DETACH, vdid

; Attach a vdata which stores one of the attribute values.

vdid = HDF_VD_ATTACH(fid, 5)

; Get the vdata's name and check to see that it is indeed storing

; an attribute.

HDF_VD_GET, vdid, NAME = vdname

isattr = HDF_VD_ISATTR(vdid)

HELP, vdname, isattr

; End access to the vdata and the HDF file.

HDF_VD_DETACH, vdid

HDF_CLOSE, fid

### IDL Output

Number of attributes attached to vdata MetObs: 2

ATTR_NAME STRING = 'vdata_contents'

METOBS_CONTENTS STRING = 'Ground station meteorological observations.'

NUM_STATIONS INT = Array[1]

HDFTYPE STRING = 'DFNT_INT16'

IDLTYPE STRING = 'INT'

10

Number of attributes attached to field TempDP: 1

COUNT LONG = 41

HDFTYPE STRING = 'DFNT_CHAR8'

IDLTYPE STRING = 'STRING'

DPTEMP_ATTR STRING = 'Dew point temperature in degrees Celsius.'

VDNAME STRING = 'field_contents'

ISATTR LONG = 1

## Version History

5.5 | Introduced

## See Also

HDF_VD_ATTRFIND, HDF_VD_ATTRINFO, HDF_VD_ISATTR, HDF_VD_NATTRS